1 # Copyright 1999-2021 Gentoo Authors |
|
2 # Distributed under the terms of the GNU General Public License v2 |
|
3 |
|
4 EAPI=7 |
|
5 |
|
6 inherit fcaps meson |
|
7 |
|
8 DESCRIPTION="Pluggable, composable, unopinionated modules for building a Wayland compositor" |
|
9 HOMEPAGE="https://github.com/swaywm/wlroots" |
|
10 |
|
11 if [[ ${PV} == 9999 ]]; then |
|
12 EGIT_REPO_URI="https://github.com/swaywm/${PN}.git" |
|
13 inherit git-r3 |
|
14 else |
|
15 SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz" |
|
16 KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86" |
|
17 fi |
|
18 |
|
19 LICENSE="MIT" |
|
20 SLOT="0/13" |
|
21 IUSE="elogind icccm seatd systemd x11-backend X" |
|
22 REQUIRED_USE="?? ( elogind systemd )" |
|
23 |
|
24 DEPEND=" |
|
25 >=dev-libs/libinput-1.14.0:0= |
|
26 >=dev-libs/wayland-1.19.0 |
|
27 >=dev-libs/wayland-protocols-1.17.0 |
|
28 media-libs/mesa[egl,gles2,gbm] |
|
29 virtual/libudev |
|
30 x11-libs/libdrm |
|
31 x11-libs/libxkbcommon |
|
32 x11-libs/pixman |
|
33 elogind? ( >=sys-auth/elogind-237 ) |
|
34 icccm? ( x11-libs/xcb-util-wm ) |
|
35 seatd? ( sys-auth/seatd:= ) |
|
36 systemd? ( >=sys-apps/systemd-237 ) |
|
37 x11-backend? ( x11-libs/libxcb:0= ) |
|
38 X? ( |
|
39 x11-base/xorg-server[wayland] |
|
40 x11-libs/libxcb:0= |
|
41 x11-libs/xcb-util-image |
|
42 ) |
|
43 " |
|
44 RDEPEND=" |
|
45 ${DEPEND} |
|
46 " |
|
47 BDEPEND=" |
|
48 >=dev-libs/wayland-protocols-1.17 |
|
49 >=dev-util/meson-0.56.0 |
|
50 virtual/pkgconfig |
|
51 " |
|
52 |
|
53 src_configure() { |
|
54 # xcb-util-errors is not on Gentoo Repository (and upstream seems inactive?) |
|
55 local emesonargs=( |
|
56 "-Dxcb-errors=disabled" |
|
57 -Dxcb-icccm=$(usex icccm enabled disabled) |
|
58 -Dxwayland=$(usex X enabled disabled) |
|
59 -Dx11-backend=$(usex x11-backend enabled disabled) |
|
60 "-Dexamples=false" |
|
61 "-Dwerror=false" |
|
62 -Dlibseat=$(usex seatd enabled disabled) |
|
63 ) |
|
64 if use systemd; then |
|
65 emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=systemd") |
|
66 elif use elogind; then |
|
67 emesonargs+=("-Dlogind=enabled" "-Dlogind-provider=elogind") |
|
68 else |
|
69 emesonargs+=("-Dlogind=disabled") |
|
70 fi |
|
71 |
|
72 meson_src_configure |
|
73 } |
|
74 |
|
75 pkg_postinst() { |
|
76 elog "You must be in the input group to allow your compositor" |
|
77 elog "to access input devices via libinput." |
|
78 } |
|