1 # Copyright 2019-2021 Gentoo Authors

     2 # Distributed under the terms of the GNU General Public License v2

     3 

     4 EAPI=7

     5 

     6 inherit toolchain-funcs

     7 

     8 DESCRIPTION="Wayland compositor inspired by CWM"

     9 HOMEPAGE="https://hikari.acmelabs.space/"

    10 SRC_URI="https://hikari.acmelabs.space/releases/${P}.tar.gz"

    11 KEYWORDS="~amd64 ~x86"

    12 

    13 LICENSE="MIT"

    14 SLOT="0"

    15 IUSE="gamma layershell screencopy suid virtual-io +X"

    16 

    17 DEPEND="

    18 	dev-libs/libinput:=

    19 	dev-libs/libucl

    20 	>=gui-libs/wlroots-0.11.0[X?]

    21 	media-libs/libglvnd

    22 	x11-libs/cairo[X?,svg]

    23 	x11-libs/libxkbcommon[X?]

    24 	x11-libs/pango[X?]

    25 	x11-libs/pixman

    26 	sys-libs/pam

    27 "

    28 

    29 RDEPEND="

    30 	${DEPEND}

    31 	x11-misc/xkeyboard-config

    32 "

    33 

    34 # Needeed in DEPEND only (not BDEPEND as need to be right location etc)

    35 DEPEND+=" dev-libs/wayland-protocols"

    36 

    37 BDEPEND="

    38 	sys-devel/bmake

    39 	virtual/pkgconfig

    40 "

    41 

    42 PATCHES=( "${FILESDIR}"/${PN}-2.2.1-pkgconfig.patch )

    43 

    44 pkg_setup() {

    45 	export MAKE=bmake

    46 	tc-export CC PKG_CONFIG

    47 }

    48 

    49 src_compile() {

    50 	emake \

    51 		VERSION="${PV}" \

    52 		CC="$(tc-getCC)" \

    53 		CFLAGS_EXTRA="${CFLAGS}" \

    54 		LDFLAGS_EXTRA="${LDFLAGS}" \

    55 		-DWITH_POSIX_C_SOURCE \

    56 		$(usex gamma -DWITH_GAMMACONTROL "") \

    57 		$(usex layershell -DWITH_LAYERSHELL "") \

    58 		$(usex screencopy -DWITH_SCREENCOPY "") \

    59 		$(usex virtual-io -DWITH_VIRTUAL_INPUT "") \

    60 		$(usex X -DWITH_XWAYLAND "") \

    61 		all

    62 }

    63 

    64 src_install() {

    65 	emake \

    66 		DESTDIR="${D}" \

    67 		PREFIX=/usr \

    68 		ETC_PREFIX=/ \

    69 		$(usex suid "" -DWITHOUT_SUID) \

    70 		install

    71 

    72 	doman share/man/man1/hikari.1

    73 }