# Copyright 2019-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit toolchain-funcs

DESCRIPTION="Wayland compositor inspired by CWM"
HOMEPAGE="https://hikari.acmelabs.space/"
if [[ ${PV} == 9999 ]]; then
	EDARCS_REPOSITORY="https://hub.darcs.net/raichoo/hikari"
	inherit darcs
	SRC_URI=""
else
	SRC_URI="https://hikari.acmelabs.space/releases/${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="MIT"
SLOT="0"
IUSE="gamma layershell screencopy suid virtual-io +X"

DEPEND="
	dev-libs/libinput:=
	dev-libs/libucl
	>=gui-libs/wlroots-0.13.0[X?]
	media-libs/libglvnd
	x11-libs/cairo[X?,svg]
	x11-libs/libxkbcommon[X?]
	x11-libs/pango[X?]
	x11-libs/pixman
	sys-libs/pam
"

RDEPEND="
	${DEPEND}
	x11-misc/xkeyboard-config
"

# Needed in DEPEND only, as it needs to be right location, whatever that means
DEPEND+=" dev-libs/wayland-protocols"

BDEPEND="
	virtual/pkgconfig
	sys-devel/bmake
"

if [[ ${PV} == 9999 ]]; then
	src_unpack() {
		darcs_src_unpack
		default
		# We copy a precompiled version of the manpage to avoid pandoc
		cp ${FILESDIR}/hikari.1 ${WORKDIR}/${PF}/share/man/man1 || die
	}
fi

pkg_setup() {
	# We set `bmake` and we also have to remove any reference to -l in MAKEOPTS
	# as `bamke` does not support load average
	# We do this in a crude way until flag-o-matic supports MAKEOPTS
	# bug 778191
	export MAKE=bmake
	MAKEOPTS=`echo $MAKEOPTS | sed 's/-l \?[\.0-9]\+//'`

	tc-export CC PKG_CONFIG
}

src_compile() {
	emake \
		VERSION="${PV}" \
		CC="$(tc-getCC)" \
		CFLAGS_EXTRA="${CFLAGS}" \
		LDFLAGS_EXTRA="${LDFLAGS}" \
		-DWITH_POSIX_C_SOURCE \
		$(usex gamma -DWITH_GAMMACONTROL "") \
		$(usex layershell -DWITH_LAYERSHELL "") \
		$(usex screencopy -DWITH_SCREENCOPY "") \
		$(usex suid -DWITH_SUID "") \
		$(usex virtual-io -DWITH_VIRTUAL_INPUT "") \
		$(usex X -DWITH_XWAYLAND "") \
		all
}

src_install() {
	emake \
		DESTDIR="${D}" \
		PREFIX=/usr \
		ETC_PREFIX=/ \
		$(usex suid -DWITH_SUID "") \
		install

	doman share/man/man1/hikari.1
}